NUTS-RDF in GeoSPARQL

The NUTS (Nomenclature of territorial units for statistics classification) representing the regions in the EU have been converted from NeoGeo to GeoSPARQL structures using a Construct SPARQL query. The purpose of the conversion is to enable GeoSPARQL spatial reasoning features for geometry-based queries.

The nuts-rdf file used as input in the conversion process is http://nuts.geovocab.org/data/0.91/nuts-rdf-0.91.ttl, which contains a dump from all the regions in the EU defined in 2013.

The nuts-rdf file has been uploaded to a triplestore, and then, the following Construct SPARQL query was run to generate the EU-nuts-rdf-geosparql.ttl file.

PREFIX rdf:
PREFIX nuts:
PREFIX ngeo:
PREFIX geo:
PREFIX geosparql:
PREFIX dc:
PREFIX rdfs:
PREFIX ramon:

CONSTRUCT {    
    ?entity a geosparql:Feature ;
            geosparql:hasGeometry ?entityGeo ;
            rdfs:label ?label ;
            ramon:name ?name ;
            ramon:level ?level ;
            ramon:code ?code .
    ?entityGeo a geosparql:Geometry ;
               dc:rights ?entityrights ;
               geosparql:asWKT ?polygon .
}
WHERE {
    {
        SELECT ?entity (GROUP_CONCAT(?lonlatpair; separator=", ") AS ?lonlatlist)
        WHERE {
            {
                SELECT ?entity ?list
                WHERE{
                    ?entity ngeo:geometry/ngeo:exterior/ngeo:posList ?list .
                }
            }
            ?list rdf:rest* [ rdf:first ?item ] .
            ?item geo:long ?lon ;
                  geo:lat ?lat .
            BIND(CONCAT(?lon, " ", ?lat) AS ?lonlatpair)
        }
        GROUP BY ?entity
    }
    # Get entity descriptors
    ?entity ngeo:geometry/dc:rights ?entityrights .
    ?entity rdfs:label ?label ;
            ramon:name ?name ;
            ramon:level ?level ;
            ramon:code ?code .
    # Define uri for the geometry
    BIND(IRI(CONCAT(STR(?entity), "-geo")) AS ?entityGeo)
    BIND(STRDT(CONCAT("POLYGON ((",STR(?lonlatlist), "))"), geosparql:wktLiteral)AS ?polygon)
}